omz

3 files changed, 313 insertions, 0 deletions

diff --git a/home/.oh-my-zsh/plugins/jira/README.md b/home/.oh-my-zsh/plugins/jira/README.md
new file mode 100644
index 0000000..f6e2e26
--- /dev/null
+++ b/home/.oh-my-zsh/plugins/jira/README.md
@@ -0,0 +1,103 @@
+# Jira plugin
+
+This plugin provides command line tools for interacting with Atlassian's [JIRA](https://www.atlassian.com/software/jira) bug tracking software.
+
+To use it, add `jira` to the plugins array in your zshrc file:
+
+```zsh
+plugins=(... jira)
+```
+
+The interaction is all done through the web. No local installation of JIRA is necessary.
+
+In this document, "JIRA" refers to the JIRA issue tracking server, and `jira` refers to the command this plugin supplies.
+
+## Usage
+
+This plugin supplies one command, `jira`, through which all its features are exposed. Most forms of this command open a JIRA page in your web browser.
+
+## Commands
+
+`jira help` or `jira usage` will print the below usage instructions
+
+| Command                       | Description                                              |
+| :---------------------------- | :------------------------------------------------------- |
+| `jira`                        | Performs the default action                              |
+| `jira new`                    | Opens a new Jira issue dialogue                          |
+| `jira ABC-123`                | Opens an existing issue                                  |
+| `jira ABC-123 m`              | Opens an existing issue for adding a comment             |
+| `jira project ABC`            | Opens JIRA project summary                               |
+| `jira dashboard [rapid_view]` | Opens your JIRA dashboard                                |
+| `jira mine`                   | Queries for your own issues                              |
+| `jira tempo`                  | Opens your JIRA Tempo                                    |
+| `jira reported [username]`    | Queries for issues reported by a user                    |
+| `jira assigned [username]`    | Queries for issues assigned to a user                    |
+| `jira branch`                 | Opens an existing issue matching the current branch name |
+| `jira help`                   | Prints usage instructions                                |
+
+
+### Jira Branch usage notes
+
+The branch name may have prefixes ending in "/": "feature/MP-1234", and also suffixes
+starting with "_": "MP-1234_fix_dashboard". In both these cases, the issue opened will be "MP-1234"
+
+This is also checks if the prefix is in the name, and adds it if not, so: "MP-1234" opens the issue "MP-1234",
+"mp-1234" opens the issue "mp-1234", and "1234" opens the issue "MP-1234".
+
+If your branch naming convention deviates, you can overwrite the jira_branch function to determine and echo the Jira issue key yourself.
+Define a function `jira_branch` after sourcing `oh-my-zsh.sh` in your `.zshrc`.
+Example:
+```zsh
+# Determine branch name from naming convention 'type/KEY-123/description'.
+function jira_branch() {
+  # Get name of the branch
+  issue_arg=$(git rev-parse --abbrev-ref HEAD)
+  # Strip prefixes like feature/ or bugfix/
+  issue_arg=${issue_arg#*/}
+  # Strip suffixes like /some-branch-description
+  issue_arg=${issue_arg%%/*}
+  # Return the value
+  echo $issue_arg
+}
+```
+
+
+#### Debugging usage
+
+These calling forms are for developers' use, and may change at any time.
+
+```
+jira dumpconfig   # displays the effective configuration
+```
+
+## Setup
+
+The URL for your JIRA instance is set by `$JIRA_URL` or a `.jira_url` file.
+
+Add a `.jira-url` file in the base of your project. You can also set `$JIRA_URL` in your `~/.zshrc` or put a `.jira-url` in your home directory. A `.jira-url` in the current directory takes precedence, so you can make per-project customizations.
+
+The same goes with `.jira-prefix` and `$JIRA_PREFIX`. These control the prefix added to all issue IDs, which differentiates projects within a JIRA instance.
+
+For example:
+
+```
+cd to/my/project
+echo "https://jira.atlassian.com" >> .jira-url
+```
+
+(Note: The current implementation only looks in the current directory for `.jira-url` and `.jira-prefix`, not up the path, so if you are in a subdirectory of your project, it will fall back to your default JIRA URL. This will probably change in the future though.)
+
+### Variables
+
+* `$JIRA_URL` - Your JIRA instance's URL
+* `$JIRA_NAME` - Your JIRA username; used as the default user for `assigned`/`reported` searches
+* `$JIRA_PREFIX` - Prefix added to issue ID arguments
+* `$JIRA_RAPID_BOARD` - Set to `true` if you use Rapid Board
+* `$JIRA_RAPID_VIEW` - Set the default rapid view; it doesn't work if `$JIRA_RAPID_BOARD` is set to false
+* `$JIRA_DEFAULT_ACTION` - Action to do when `jira` is called with no arguments; defaults to "new"
+* `$JIRA_TEMPO_PATH` - Your JIRA tempo url path; defaults to "/secure/Tempo.jspa"
+
+
+### Browser
+
+Your default web browser, as determined by how `open_command` handles `http://` URLs, is used for interacting with the JIRA instance. If you change your system's URL handler associations, it will change the browser that `jira` uses.
diff --git a/home/.oh-my-zsh/plugins/jira/_jira b/home/.oh-my-zsh/plugins/jira/_jira
new file mode 100644
index 0000000..617a3e5
--- /dev/null
+++ b/home/.oh-my-zsh/plugins/jira/_jira
@@ -0,0 +1,27 @@
+#compdef jira
+#autoload
+
+local -a _1st_arguments
+_1st_arguments=(
+  'new:create a new issue'
+  'mine:open my issues'
+  'project:open the project'
+  'dashboard:open the dashboard'
+  'tempo:open the tempo'
+  'reported:search for issues reported by a user'
+  'assigned:search for issues assigned to a user'
+  'branch:open the issue named after the git branch of the current directory'
+  'dumpconfig:display effective jira configuration'
+  'help:print usage help to stdout'
+)
+
+_arguments -C \
+  ':command:->command' \
+  '*::options:->options'
+
+case $state in
+  (command)
+    _describe -t commands "jira subcommand" _1st_arguments
+    return
+   ;;
+esac
diff --git a/home/.oh-my-zsh/plugins/jira/jira.plugin.zsh b/home/.oh-my-zsh/plugins/jira/jira.plugin.zsh
new file mode 100644
index 0000000..0c90544
--- /dev/null
+++ b/home/.oh-my-zsh/plugins/jira/jira.plugin.zsh
@@ -0,0 +1,183 @@
+# CLI support for JIRA interaction
+#
+# See README.md for details
+
+function _jira_usage() {
+cat <<EOF
+jira                            Performs the default action
+jira new                        Opens a new Jira issue dialogue
+jira ABC-123                    Opens an existing issue
+jira ABC-123 m                  Opens an existing issue for adding a comment
+jira project ABC                Opens JIRA project summary
+jira dashboard [rapid_view]     Opens your JIRA dashboard
+jira mine                       Queries for your own issues
+jira tempo                      Opens your JIRA Tempo
+jira reported [username]        Queries for issues reported by a user
+jira assigned [username]        Queries for issues assigned to a user
+jira branch                     Opens an existing issue matching the current branch name
+EOF
+}
+
+# If your branch naming convention deviates, you can partially override this plugin function
+# to determine the jira issue key based on your formatting.
+# See https://github.com/ohmyzsh/ohmyzsh/wiki/Customization#partially-overriding-an-existing-plugin
+function jira_branch() {
+  # Get name of the branch
+  issue_arg=$(git rev-parse --abbrev-ref HEAD)
+  # Strip prefixes like feature/ or bugfix/
+  issue_arg=${issue_arg##*/}
+  # Strip suffixes starting with _
+  issue_arg=(${(s:_:)issue_arg})
+  # If there is only one part, it means that there is a different delimiter. Try with -
+  if [[ ${#issue_arg[@]} = 1 && ${issue_arg} == *-* ]]; then
+    issue_arg=(${(s:-:)issue_arg})
+    issue_arg="${issue_arg[1]}-${issue_arg[2]}"
+  else
+    issue_arg=${issue_arg[1]}
+  fi
+  if [[ "${issue_arg:l}" = ${jira_prefix:l}* ]]; then
+    echo "${issue_arg}"
+  else
+    echo "${jira_prefix}${issue_arg}"
+  fi
+}
+
+function jira() {
+  emulate -L zsh
+  local action jira_url jira_prefix
+  if [[ -n "$1" ]]; then
+    action=$1
+  elif [[ -f .jira-default-action ]]; then
+    action=$(cat .jira-default-action)
+  elif [[ -f ~/.jira-default-action ]]; then
+    action=$(cat ~/.jira-default-action)
+  elif [[ -n "${JIRA_DEFAULT_ACTION}" ]]; then
+    action=${JIRA_DEFAULT_ACTION}
+  else
+    action="new"
+  fi
+
+  if [[ -f .jira-url ]]; then
+    jira_url=$(cat .jira-url)
+  elif [[ -f ~/.jira-url ]]; then
+    jira_url=$(cat ~/.jira-url)
+  elif [[ -n "${JIRA_URL}" ]]; then
+    jira_url=${JIRA_URL}
+  else
+    _jira_url_help
+    return 1
+  fi
+
+  if [[ -f .jira-prefix ]]; then
+    jira_prefix=$(cat .jira-prefix)
+  elif [[ -f ~/.jira-prefix ]]; then
+    jira_prefix=$(cat ~/.jira-prefix)
+  elif [[ -n "${JIRA_PREFIX}" ]]; then
+    jira_prefix=${JIRA_PREFIX}
+  else
+    jira_prefix=""
+  fi
+
+
+  if [[ $action == "new" ]]; then
+    echo "Opening new issue"
+    open_command "${jira_url}/secure/CreateIssue!default.jspa"
+  elif [[ "$action" == "assigned" || "$action" == "reported" ]]; then
+    _jira_query ${@:-$action}
+  elif [[ "$action" == "help" || "$action" == "usage" ]]; then
+    _jira_usage
+  elif [[ "$action" == "mine" ]]; then
+    echo "Opening my issues"
+    open_command "${jira_url}/issues/?filter=-1"
+  elif [[ "$action" == "project" ]]; then
+    echo "Opening project"
+    open_command "${jira_url}/jira/software/c/projects/${2}/summary"
+  elif [[ "$action" == "dashboard" ]]; then
+    echo "Opening dashboard"
+    if [[ "$JIRA_RAPID_BOARD" == "true" ]]; then
+      _jira_rapid_board ${@}
+    else
+      open_command "${jira_url}/secure/Dashboard.jspa"
+    fi
+  elif [[ "$action" == "tempo" ]]; then
+    echo "Opening tempo"
+    if [[ -n "$JIRA_TEMPO_PATH" ]]; then
+      open_command "${jira_url}${JIRA_TEMPO_PATH}"
+    else
+      open_command "${jira_url}/secure/Tempo.jspa"
+    fi
+  elif [[ "$action" == "dumpconfig" ]]; then
+    echo "JIRA_URL=$jira_url"
+    echo "JIRA_PREFIX=$jira_prefix"
+    echo "JIRA_NAME=$JIRA_NAME"
+    echo "JIRA_RAPID_VIEW=$JIRA_RAPID_VIEW"
+    echo "JIRA_RAPID_BOARD=$JIRA_RAPID_BOARD"
+    echo "JIRA_DEFAULT_ACTION=$JIRA_DEFAULT_ACTION"
+    echo "JIRA_TEMPO_PATH=$JIRA_TEMPO_PATH"
+  else
+    # Anything that doesn't match a special action is considered an issue name
+    # but `branch` is a special case that will parse the current git branch
+    local issue_arg issue
+    if [[ "$action" == "branch" ]]; then
+      issue=$(jira_branch)
+    else
+      issue_arg=${(U)action}
+      issue="${jira_prefix}${issue_arg}"
+    fi
+
+    local url_fragment
+    if [[ "$2" == "m" ]]; then
+      url_fragment="#add-comment"
+      echo "Add comment to issue #$issue"
+    else
+      echo "Opening issue #$issue"
+    fi
+    open_command "${jira_url}/browse/${issue}${url_fragment}"
+  fi
+}
+
+function _jira_url_help() {
+  cat << EOF
+error: JIRA URL is not specified anywhere.
+
+Valid options, in order of precedence:
+  .jira-url file
+  \$HOME/.jira-url file
+  \$JIRA_URL environment variable
+EOF
+}
+
+function _jira_rapid_board() {
+  rapid_view=${2:=$JIRA_RAPID_VIEW}
+
+  if [[ -z $rapid_view ]]; then
+    open_command "${jira_url}/secure/RapidBoard.jspa"
+  else
+    open_command "${jira_url}/secure/RapidBoard.jspa?rapidView=$rapid_view"
+  fi
+}
+
+function _jira_query() {
+  emulate -L zsh
+  local verb="$1"
+  local jira_name lookup preposition query
+  if [[ "${verb}" == "reported" ]]; then
+    lookup=reporter
+    preposition=by
+  elif [[ "${verb}" == "assigned" ]]; then
+    lookup=assignee
+    preposition=to
+  else
+    echo "error: not a valid lookup: $verb" >&2
+    return 1
+  fi
+  jira_name=${2:=$JIRA_NAME}
+  if [[ -z $jira_name ]]; then
+    echo "error: JIRA_NAME not specified" >&2
+    return 1
+  fi
+
+  echo "Browsing issues ${verb} ${preposition} ${jira_name}"
+  query="${lookup}+%3D+%22${jira_name}%22+AND+resolution+%3D+unresolved+ORDER+BY+priority+DESC%2C+created+ASC"
+  open_command "${jira_url}/secure/IssueNavigator.jspa?reset=true&jqlQuery=${query}"
+}