omz

2 files changed, 190 insertions, 0 deletions

diff --git a/home/.oh-my-zsh/plugins/python/README.md b/home/.oh-my-zsh/plugins/python/README.md
new file mode 100644
index 0000000..ca424ea
--- /dev/null
+++ b/home/.oh-my-zsh/plugins/python/README.md
@@ -0,0 +1,68 @@
+# Python plugin
+
+The plugin adds several aliases for useful [Python](https://www.python.org/) commands.
+
+To use it, add `python` to the plugins array in your zshrc file:
+
+```zsh
+plugins=(... python)
+```
+
+## Aliases
+
+| Command          | Description                                                                            |
+| ---------------- | -------------------------------------------------------------------------------------- |
+| `py`             | Runs `python3`. Only set if `py` is not installed.                                     |
+| `pyfind`         | Finds .py files recursively in the current directory                                   |
+| `pyclean [dirs]` | Deletes byte-code and cache files from a list of directories or the current one        |
+| `pygrep <text>`  | Looks for `text` in `*.py` files in the current directory, recursively                 |
+| `pyuserpaths`    | Add user site-packages folders to `PYTHONPATH`, for Python 2 and 3                     |
+| `pyserver`       | Starts an HTTP server on the current directory (use `--directory` for a different one) |
+
+## Virtual environments
+
+The plugin provides three utilities to manage Python 3.3+ [venv](https://docs.python.org/3/library/venv.html)
+virtual environments:
+
+- `mkv [name]`: make a new virtual environment called `name` in the current directory.
+  **Default**: `$PYTHON_VENV_NAME` if set, otherwise `venv`.
+
+- `vrun [name]`: activate the virtual environment called `name` in the current directory.
+  **Default**: the first existing in `$PYTHON_VENV_NAMES`.
+
+- `auto_vrun`: automatically activate the venv virtual environment when entering a directory containing
+  `<venv-name>/bin/activate`, and automatically deactivate it when navigating out of it (keeps venv activated
+  in subdirectories).
+  - To enable the feature, set `PYTHON_AUTO_VRUN=true` before sourcing oh-my-zsh.
+  - The plugin activates the first existing virtual environment, in order, appearing in `$PYTHON_VENV_NAMES`.
+    The default virtual environment name is `venv`. To use a different name, set
+    `PYTHON_VENV_NAME=<venv-name>`. For example: `PYTHON_VENV_NAME=".venv"`
+
+### Settings
+
+You can set these variables in your `.zshrc` file, before Oh My Zsh is sourced.
+For example:
+
+```sh
+PYTHON_VENV_NAME=".venv"
+PYTHON_VENV_NAMES=($PYTHON_VENV_NAME venv)
+...
+plugins=(... python)
+source "$ZSH/oh-my-zsh.sh"
+```
+
+
+## `$PYTHON_VENV_NAME`
+
+**Default**: `venv`.
+
+Preferred name for virtual environments, for example when creating via `mkv`.
+
+## `$PYTHON_VENV_NAMES`
+
+**Default**: `$PYTHON_VENV_NAME venv .venv`.
+
+Array of virtual environment names to be checked, in order, by `vrun` and `auto_vrun`.
+This means these functions will load the first existing virtual environment in this list.
+Duplicate names are ignored.
+
diff --git a/home/.oh-my-zsh/plugins/python/python.plugin.zsh b/home/.oh-my-zsh/plugins/python/python.plugin.zsh
new file mode 100644
index 0000000..2b139dd
--- /dev/null
+++ b/home/.oh-my-zsh/plugins/python/python.plugin.zsh
@@ -0,0 +1,122 @@
+# set python command if 'py' not installed
+builtin which py > /dev/null || alias py='python3'
+
+# Find python file
+alias pyfind='find . -name "*.py"'
+
+# Remove python compiled byte-code and mypy/pytest cache in either the current
+# directory or in a list of specified directories (including sub directories).
+function pyclean() {
+  find "${@:-.}" -type f -name "*.py[co]" -delete
+  find "${@:-.}" -type d -name "__pycache__" -delete
+  find "${@:-.}" -depth -type d -name ".mypy_cache" -exec rm -r "{}" +
+  find "${@:-.}" -depth -type d -name ".pytest_cache" -exec rm -r "{}" +
+}
+
+# Add the user installed site-packages paths to PYTHONPATH, only if the
+#   directory exists. Also preserve the current PYTHONPATH value.
+# Feel free to autorun this when .zshrc loads.
+function pyuserpaths() {
+  setopt localoptions extendedglob
+
+  # Check for a non-standard install directory.
+  local user_base="${PYTHONUSERBASE:-"${HOME}/.local"}"
+
+  local python version site_pkgs
+  for python in python2 python3; do
+    # Check if command exists
+    (( ${+commands[$python]} )) || continue
+
+    # Get minor release version.
+    # The patch version is variable length, truncate it.
+    version=${(M)${"$($python -V 2>&1)":7}#[^.]##.[^.]##}
+
+    # Add version specific path, if:
+    # - it exists in the filesystem
+    # - it isn't in $PYTHONPATH already.
+    site_pkgs="${user_base}/lib/python${version}/site-packages"
+    [[ -d "$site_pkgs" && ! "$PYTHONPATH" =~ (^|:)"$site_pkgs"(:|$) ]] || continue
+    export PYTHONPATH="${site_pkgs}${PYTHONPATH+":${PYTHONPATH}"}"
+  done
+}
+
+# Grep among .py files
+alias pygrep='grep -nr --include="*.py"'
+
+# Share local directory as a HTTP server
+alias pyserver="python3 -m http.server"
+
+
+## venv settings
+: ${PYTHON_VENV_NAME:=venv}
+
+# Array of possible virtual environment names to look for, in order
+# -U for removing duplicates
+typeset -gaU PYTHON_VENV_NAMES
+[[ -n "$PYTHON_VENV_NAMES" ]] || PYTHON_VENV_NAMES=($PYTHON_VENV_NAME venv .venv)
+
+# Activate a the python virtual environment specified.
+# If none specified, use the first existing in $PYTHON_VENV_NAMES.
+function vrun() {
+  if [[ -z "$1" ]]; then
+    local name
+    for name in $PYTHON_VENV_NAMES; do
+      local venvpath="${name:P}"
+      if [[ -d "$venvpath" ]]; then
+        vrun "$name"
+        return $?
+      fi
+    done
+    echo >&2 "Error: no virtual environment found in current directory"
+  fi
+
+  local name="${1:-$PYTHON_VENV_NAME}"
+  local venvpath="${name:P}"
+
+  if [[ ! -d "$venvpath" ]]; then
+    echo >&2 "Error: no such venv in current directory: $name"
+    return 1
+  fi
+
+  if [[ ! -f "${venvpath}/bin/activate" ]]; then
+    echo >&2 "Error: '${name}' is not a proper virtual environment"
+    return 1
+  fi
+
+  . "${venvpath}/bin/activate" || return $?
+  echo "Activated virtual environment ${name}"
+}
+
+# Create a new virtual environment using the specified name.
+# If none specified, use $PYTHON_VENV_NAME
+function mkv() {
+  local name="${1:-$PYTHON_VENV_NAME}"
+  local venvpath="${name:P}"
+
+  python3 -m venv "${name}" || return
+  echo >&2 "Created venv in '${venvpath}'"
+  vrun "${name}"
+}
+
+if [[ "$PYTHON_AUTO_VRUN" == "true" ]]; then
+  # Automatically activate venv when changing dir
+  function auto_vrun() {
+    # deactivate if we're on a different dir than VIRTUAL_ENV states
+    # we don't deactivate subdirectories!
+    if (( $+functions[deactivate] )) && [[ $PWD != ${VIRTUAL_ENV:h}* ]]; then
+      deactivate > /dev/null 2>&1
+    fi
+
+    if [[ $PWD != ${VIRTUAL_ENV:h} ]]; then
+      local file
+      for file in "${^PYTHON_VENV_NAMES[@]}"/bin/activate(N.); do
+        # make sure we're not in a venv already
+        (( $+functions[deactivate] )) && deactivate > /dev/null 2>&1
+        source $file > /dev/null 2>&1
+        break
+      done
+    fi
+  }
+  add-zsh-hook chpwd auto_vrun
+  auto_vrun
+fi