1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
|
/**
* vim: set ts=4 :
* =============================================================================
* sm-json
* Provides a pure SourcePawn implementation of JSON encoding and decoding.
* https://github.com/clugg/sm-json
*
* sm-json (C)2019 James Dickens. (clug)
* SourceMod (C)2004-2008 AlliedModders LLC. All rights reserved.
* =============================================================================
*
* This program is free software; you can redistribute it and/or modify it under
* the terms of the GNU General Public License, version 3.0, as published by the
* Free Software Foundation.
*
* This program is distributed in the hope that it will be useful, but WITHOUT
* ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
* FOR A PARTICULAR PURPOSE. See the GNU General Public License for more
* details.
*
* You should have received a copy of the GNU General Public License along with
* this program. If not, see <http://www.gnu.org/licenses/>.
*
* As a special exception, AlliedModders LLC gives you permission to link the
* code of this program (as well as its derivative works) to "Half-Life 2," the
* "Source Engine," the "SourcePawn JIT," and any Game MODs that run on software
* by the Valve Corporation. You must obey the GNU General Public License in
* all respects for all other code used. Additionally, AlliedModders LLC grants
* this exception to all derivative works. AlliedModders LLC defines further
* exceptions, found in LICENSE.txt (as of this writing, version JULY-31-2007),
* or <http://www.sourcemod.net/license.php>.
*/
#if defined _json_helpers_encode_included
#endinput
#endif
#define _json_helpers_encode_included
#include <string>
/**
* @section Calculate Buffer Size for Value
*/
/**
* Calculates the maximum buffer length required to
* store the JSON cell representation of a string.
*
* @param length The length of the string.
* @returns Maximum buffer length.
*/
stock int json_cell_string_size(int length)
{
// double for potential escaping, + 2 for outside quotes + NULL terminator
return (length * 2) + 3;
}
/**
* Calculates the maximum buffer length required to
* store the JSON cell representation of an int.
*
* @param input Value to calculate maximum buffer length for.
* @returns Maximum buffer length.
*/
stock int json_cell_int_size(int input)
{
if (input == 0) {
// "0" + NULL terminator
return 2;
}
int result = 0;
if (input < 0) {
// negative sign
result += 1;
}
// calculate number of digits in number
result += RoundToFloor(Logarithm(FloatAbs(float(input)), 10.0)) + 1;
// NULL terminator
result += 1;
return result;
}
/**
* Calculates the maximum buffer length required to
* store the JSON cell representation of a float.
*
* @returns Maximum buffer length.
*/
stock int json_cell_float_size()
{
return JSON_FLOAT_BUFFER_SIZE;
}
/**
* Calculates the maximum buffer length required to
* store the JSON cell representation of a bool.
*
* @returns Maximum buffer length.
*/
stock int json_cell_bool_size()
{
// "true"|"false" + NULL terminator
return 6;
}
/**
* Calculates the maximum buffer length required to
* store the JSON cell representation of null.
*
* @returns Maximum buffer length.
*/
stock int json_cell_null_size()
{
// "null" + NULL terminator
return 5;
}
/**
* @section Convert Values to JSON Cells
*/
/**
* Generates the JSON cell representation of a string.
*
* @param input Value to generate output for.
* @param output String buffer to store output.
* @param max_size Maximum size of string buffer.
*/
stock void json_cell_string(const char[] input, char[] output, int max_size)
{
// add dummy char that won't be escaped to replace with a quote later
strcopy(output, max_size, "?");
// add input string to output
StrCat(output, max_size, input);
// escape the output string
json_escape_string(output, max_size);
// surround string with quotations
output[0] = '"';
StrCat(output, max_size, "\"");
}
/**
* Generates the JSON cell representation of an int.
*
* @param input Value to generate output for.
* @param output String buffer to store output.
* @param max_size Maximum size of string buffer.
*/
stock void json_cell_int(int input, char[] output, int max_size)
{
IntToString(input, output, max_size);
}
/**
* Generates the JSON cell representation of a float.
*
* @param input Value to generate output for.
* @param output String buffer to store output.
* @param max_size Maximum size of string buffer.
*/
stock void json_cell_float(float input, char[] output, int max_size)
{
FloatToString(input, output, max_size);
// trim trailing 0s from float output up until decimal point
int last_char = strlen(output) - 1;
while (output[last_char] == '0' && output[last_char - 1] != '.') {
output[last_char--] = '\0';
}
}
/**
* Generates the JSON cell representation of a bool.
*
* @param input Value to generate output for.
* @param output String buffer to store output.
* @param max_size Maximum size of string buffer.
*/
stock void json_cell_bool(bool input, char[] output, int max_size)
{
strcopy(output, max_size, (input) ? "true" : "false");
}
/**
* Generates the JSON cell representation of null.
*
* @param output String buffer to store output.
* @param max_size Maximum size of string buffer.
*/
stock void json_cell_null(char[] output, int max_size)
{
strcopy(output, max_size, "null");
}
|
